-
Notifications
You must be signed in to change notification settings - Fork 1
/
night.ahk
2521 lines (2065 loc) · 75.2 KB
/
night.ahk
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
#SingleInstance Force
#MenuMaskKey vkFF
#NoEnv
if (!A_IsUnicode || A_PtrSize != 8) {
ExitApp
}
DetectHiddenWindows On
SetTitleMatchMode RegEx
Join(Items, Separator) {
loop % Items.Count() {
if (A_Index == 1) {
String := "" Items[A_Index]
continue
}
String := String Separator Items[A_Index]
}
return String
}
JoinPath(Path, ChildPath) {
VarSetCapacity(Joined, 260 << !!A_IsUnicode, 1)
DllCall("shlwapi\PathCombine", "UInt", &Joined, "UInt", &Path, "UInt", &ChildPath)
return Joined
}
EnsureTrailingBackslash(String) {
if (SubStr(String, 0, 1) != "\") {
return String "\"
}
return String
}
ReadFileUtf8(Path) {
FileRead Data, % "*P65001 " Path
return Data
}
ConsumeFileUtf8(Path) {
Data := ReadFileUtf8(Path)
FileDelete % Path
return Data
}
WriteFileUtf8(Path, Data) {
FileDelete % Path
FileAppend % Data, % Path, % "UTF-8-RAW"
}
GenerateRandomGuid() {
return ComObjCreate("Scriptlet.TypeLib").GUID
}
CreateTempFilePath() {
loop {
Path := JoinPath(A_Temp, GenerateRandomGuid())
if (!FileExist(Path)) {
return Path
}
}
}
HashFile(Path, Algorithm) {
OutputPath := CreateTempFilePath()
Shell := ComObjCreate("WScript.Shell")
Shell.Run("cmd /c certutil -hashfile """ Path """ " Algorithm " >" OutputPath, 0, true)
return StrSplit(ConsumeFileUtf8(OutputPath), "`n", "`r", 3)[2]
}
LoadXml(String) {
Xml := ComObjCreate("MSXML2.DOMDocument.6.0")
Xml.setProperty("SelectionLanguage", "XPath")
Xml.async := false
if (!Xml.loadXML(String)) {
return
}
return Xml
}
GetFileVersionInfo(Path, Fields) {
; https://www.autohotkey.com/boards/viewtopic.php?p=46622#p46622
Size := DllCall("version\GetFileVersionInfoSize", "Str", Path, "Ptr", 0, "UInt")
Size := VarSetCapacity(Data, Size + A_PtrSize)
DllCall("version\GetFileVersionInfo", "Str", Path, "UInt", 0, "UInt", Size, "Ptr", &Data)
DllCall("version\VerQueryValue", "Ptr", &Data, "Str", "\VarFileInfo\Translation", "PtrP", VersionInfo, "PtrP", VersionInfoSize)
Language := Format("{:04X}{:04X}", NumGet(VersionInfo + 0, "UShort"), NumGet(VersionInfo + 2, "UShort"))
Info := {}
for _, Field in Fields {
if (DllCall("version\VerQueryValue", "Ptr", &Data, "Str", "\StringFileInfo\" Language "\" Field, "PtrP", VersionInfo, "PtrP", VersionInfoSize, "Int")) {
Info[Field] := StrGet(VersionInfo, VersionInfoSize)
}
}
return Info
}
MapFile(FileHandle, ByRef Address) {
Mapping := DllCall("CreateFileMapping", "Ptr", FileHandle, "Ptr", 0, "Int", 0x4, "Int", 0, "Int", 0, "Ptr", 0, "Ptr")
if (!Mapping) {
return false
}
Address := DllCall("MapViewOfFile", "Ptr", Mapping, "Int", 0xF001F, "Int", 0, "Int", 0, "Ptr", 0, "Ptr")
if (!Address) {
DllCall("CloseHandle", "Ptr", Mapping)
return false
}
return Mapping
}
UnmapFile(Mapping, Address) {
DllCall("UnmapViewOfFile", "Ptr", Address)
DllCall("CloseHandle", "Ptr", Mapping)
}
SearchBytesInBytes(Address, Count, SearchAddress, SearchCount) {
static Bin
if (!VarSetCapacity(Bin)) {
; https://www.autohotkey.com/boards/viewtopic.php?t=90318
Size := CryptStringToBinary("U1ZXQVSLRCRIRItcJFCJ00Qpy4XAvgEAAABBuv////9BD07yhcB+B2dEjVD/6wgBwkGJ0kUpykGD6QFFhdJyQzHSQTnadzxEidBBijhAODwBdShEichBigQAZ0ONPAqJ/zgEOXUVQYP5AnMbg8IB6wVEOc909kQ52nRDQQHyRYXSc78xwOs9vwEAAABBg/kBdt8PH0QAAGYPH4QAAAAAAIn4QYoEAGdFjSQ6RYnkQjgEIXW9g8cBRDnPcuTrs0SJ0EgByEFcX15bwwAARYXAdjoxwEGJwUaKFAlBgPpAdhJBicNCgDwZW3MIQbsgAAAA6wNFMdtFD7bSRQHaRYjSRogUCoPAAUQ5wHLIww", Bin, 0x1)
DllCall("VirtualProtect", "Ptr", &Bin, "Ptr", Size, "UInt", 0x40, "UIntP", 0)
}
return DllCall(&Bin, "Ptr", Address, "Int", Count, "Ptr", SearchAddress, "Short", SearchCount, "Int", 1, "Int", 1, "CDecl Ptr")
}
CryptUtf8ToString(String, Flags) {
VarSetCapacity(Binary, StrPut(String, "UTF-8"))
Size := StrPut(String, &Binary, "UTF-8") - 1
return CryptBinaryToString(&Binary, Size, Flags)
}
CryptBinaryToString(Binary, Size, Flags) {
if (!DllCall("crypt32\CryptBinaryToString", "Ptr", Binary, "UInt", Size, "UInt", Flags, "Ptr", 0, "UIntP", Count, "Int")) {
return false
}
VarSetCapacity(String, Count << !!A_IsUnicode)
if (!DllCall("crypt32\CryptBinaryToString", "Ptr", Binary, "UInt", Size, "UInt", Flags, "Ptr", &String, "UIntP", Count, "Int")) {
return false
}
return StrGet(&String)
}
CryptStringToBinary(String, ByRef Binary, Flags) {
if (!DllCall("crypt32\CryptStringToBinary", "Str", String, "UInt", 0, "UInt", Flags, "Ptr", 0, "UIntP", Size, "UInt", 0, "UInt", 0, "Int")) {
return false
}
VarSetCapacity(Binary, Size)
if (!DllCall("crypt32\CryptStringToBinary", "Str", String, "UInt", 0, "UInt", Flags, "Ptr", &Binary, "UIntP", Size, "UInt", 0, "UInt", 0, "Int")) {
return false
}
return Size
}
ShellParseDisplayName(Path) {
; no way im doing THAT one
; https://en.delphipraxis.net/topic/4827-parse-pidl-from-name-located-on-portable-device/
; https://stackoverflow.com/questions/42966489/how-to-use-shcreateitemfromparsingname-with-names-from-the-shell-namespace
; https://stackoverflow.com/questions/27593315/how-can-i-iterate-across-the-photos-on-my-connected-iphone-from-windows-7-in-pyt
for Item in ComObjCreate("Shell.Application").NameSpace(0x0).Items {
if (InStr(Item.Path, "::{", true) == 1 && Item.Name == Path) {
ParsePath := "shell:" Item.Path
break
}
}
if (!ParsePath) {
static SpecialFolders := Object("Desktop", "shell:::{B4BFCC3A-DB2C-424C-B029-7FE99A87C641}"
, "Documents", "shell:::{A8CDFF1C-4878-43BE-B5FD-F8091C1C60D0}"
, "Downloads", "shell:::{374DE290-123F-4565-9164-39C4925E467B}"
, "Music", "shell:::{1CF1260C-4DD0-4EBB-811F-33C572699FDE}"
, "Pictures", "shell:::{3ADD1653-EB32-4CB0-BBD7-DFA0ABB5ACCA}"
, "Public", "shell:::{4336A54D-038B-4685-AB02-99BB52D3FB8B}"
, "Recycle Bin", "shell:::{645FF040-5081-101B-9F08-00AA002F954E}"
, "This PC", "shell:::{20D04FE0-3AEA-1069-A2D8-08002B30309D}")
ParsePath := SpecialFolders[Path]
}
if (!ParsePath) {
ParsePath := EnsureTrailingBackslash(Path)
}
DllCall("shell32\SHParseDisplayName", "Str", ParsePath, "Ptr", 0, "Ptr*", Pidl, "UInt", 0, "UInt*", 0)
return Pidl
}
ShellGetPidlPath(Pidl) {
VarSetCapacity(Path, 512)
DllCall("shell32\SHGetPathFromIDListW", "UInt", Pidl, "Str", Path)
return Path
}
ShellOpenFolderAndSelect(Path, Paths, Flags) {
PathsCount := Paths.Count()
PathPidl := ShellParseDisplayName(Path)
VarSetCapacity(PathsPidls, PathsCount * A_PtrSize, 0)
loop % Paths.Count() {
NumPut(ShellParseDisplayName(Paths[A_Index]), PathsPidls, (A_Index - 1) * A_PtrSize, "Ptr")
}
DllCall("shell32\SHOpenFolderAndSelectItems", "Ptr", PathPidl, "UInt", PathsCount, "Ptr", &PathsPidls, "Int", Flags)
DllCall("ole32\CoTaskMemFree", "Ptr", PathPidl)
loop % Paths.Count() {
DllCall("ole32\CoTaskMemFree", "Ptr", NumGet(PathsPidls, (A_Index - 1) * A_PtrSize, "Ptr"))
}
}
GetMonitorFromPoint(X, Y) {
return DllCall("MonitorFromPoint", "Int64", X | (Y << 32), "UInt", 0)
}
GetMonitorWorkArea(Monitor, ByRef X, ByRef Y, ByRef Width, ByRef Height) {
VarSetCapacity(MonitorInfo, 0x28)
NumPut(0x28, &MonitorInfo, 0x0)
DllCall("GetMonitorInfo", "Ptr", Monitor, "Ptr", &MonitorInfo)
X := NumGet(&MonitorInfo + 0x14, "Int")
Y := NumGet(&MonitorInfo + 0x18, "Int")
Width := NumGet(&MonitorInfo + 0x1c, "Int") - X
Height := NumGet(&MonitorInfo + 0x20, "Int") - Y
}
global _FindWindowChildrenRecursiveList
_FindWindowChildrenRecursiveProc(hwnd, lParam) {
_FindWindowChildrenRecursiveList.Push(hwnd)
}
global _FindWindowChildrenRecursiveCallback := RegisterCallback("_FindWindowChildrenRecursiveProc", "F")
FindWindowChildrenRecursive(Hwnd) {
_FindWindowChildrenRecursiveList := []
DllCall("EnumChildWindows", "Ptr", Hwnd, "Ptr", _FindWindowChildrenRecursiveCallback, "Ptr", 0)
return _FindWindowChildrenRecursiveList
}
SetWinEventHook(EventMin, EventMax, FuncName) {
DllCall("SetWinEventHook", "UInt", EventMin, "UInt", EventMax, "Ptr", 0, "Ptr", RegisterCallback(FuncName, "F"), "UInt", 0, "UInt", 0, "UInt", 0)
}
GetHwndClass(Hwnd) {
WinGetClass Cls, % "ahk_id " Hwnd
return Cls
}
GetControlHwndNN(Hwnd, ControlHwnd, ControlClass) {
WinGet Controls, ControlListHwnd, % "ahk_id " Hwnd
Nn := 0
loop parse, Controls, `n
{
WinGetClass Class_, % "ahk_id " A_LoopField
if (Class_ == ControlClass) {
Nn += 1
if (A_LoopField == ControlHwnd) {
break
}
}
}
return Nn
}
GetFocus(Hwnd) {
CurrentThreadId := DllCall("GetCurrentThreadId", "UInt")
HwndThreadId := DllCall("GetWindowThreadProcessId", "UInt", Hwnd, "UIntP", 0, "UInt")
if (!DllCall("AttachThreadInput", "UInt", CurrentThreadId, "UInt", HwndThreadId, "Int", 1, "Int")) {
return
}
Focus := DllCall("GetFocus", "Ptr")
DllCall("AttachThreadInput", "UInt", CurrentThreadId, "UInt", HwndThreadId, "Int", 0)
return Focus
}
SetFocus(Hwnd, ControlHwnd) {
CurrentThreadId := DllCall("GetCurrentThreadId", "UInt")
HwndThreadId := DllCall("GetWindowThreadProcessId", "UInt", Hwnd, "UIntP", 0, "UInt")
if (!DllCall("AttachThreadInput", "UInt", CurrentThreadId, "UInt", HwndThreadId, "Int", 1, "Int")) {
return
}
DllCall("SetFocus", "Ptr", ControlHwnd)
DllCall("AttachThreadInput", "UInt", CurrentThreadId, "UInt", HwndThreadId, "Int", 0)
}
global ToolTipTitle := "ahk_class ^tooltips_class32$"
ToolTip(Text := "", X := "", Y := "", Timeout := 0, WhichToolTip := "") {
static Timers := {}
if (!WhichToolTip) {
WhichToolTip := 1
}
ToolTip % Text, % X, % Y, % WhichToolTip
if (Timers[WhichToolTip]) {
F := Timers[WhichToolTip]
Timers[WhichToolTip] :=
SetTimer % F, Off
}
if (Text && Timeout) {
F := Func("ToolTip").Bind(, , , , WhichToolTip)
Timers[WhichToolTip] := F
SetTimer % F, % -Timeout
}
}
global MenuTitle := "ahk_class ^#32768$"
GetMenuItemCount(Menu) {
return DllCall("GetMenuItemCount", "Ptr", Menu, "Int")
}
GetMenuItemName(Menu, Index) {
Count := DllCall("GetMenuString", "Ptr", Menu, "UInt", Index, "Ptr", 0, "Int", 0, "UInt", 0x400, "Int") + 1
VarSetCapacity(Name, Count << !!A_IsUnicode)
DllCall("GetMenuString", "Ptr", Menu, "UInt", Index, "Str", Name, "Int", Count, "UInt", 0x400)
return Name
}
GetMenuItemState(Menu, Index) {
return DllCall("GetMenuState", "Ptr", Menu, "UInt", Index, "UInt", 0x400, "UInt")
}
FindMenuItemIndex(Menu, Name) {
loop % GetMenuItemCount(Menu) {
CurrentName := GetMenuItemName(Menu, A_Index - 1)
CurrentName := StrSplit(StrReplace(CurrentName, "&"), "`t", , 2)[1]
if (CurrentName == Name) {
return A_Index - 1
}
}
return -1
}
GetActiveMenu() {
SendMessage 0x1E1, , , , % MenuTitle
if (ErrorLevel == "FAIL") {
return false
}
return ErrorLevel
}
CloseActiveMenu() {
SendMessage 0x1E6, , , , % MenuTitle
}
OpenActiveSubMenu(Index) {
SendMessage 0x1ED, % Index, 0, , % MenuTitle
}
SelectActiveMenuItem(Index) {
PostMessage 0x1F1, % Index, 0, , % MenuTitle
}
TryOpenActiveSubMenu(Menu, Name) {
Index := FindMenuItemIndex(Menu, Name)
if (Index == -1) {
return false
}
OpenActiveSubMenu(Index)
return true
}
TrySelectActiveMenuItem(Menu, Name) {
Index := FindMenuItemIndex(Menu, Name)
if (Index == -1) {
return false
}
SelectActiveMenuItem(Index)
return true
}
global DialogTitle := "ahk_class ^#32770$"
global FileDialogListViewControlClassNN := "DirectUIHWND2"
IsDialogFileDialog(WinTitle) {
ControlGet ControlHwnd, Hwnd, , % FileDialogListViewControlClassNN, % WinTitle
return !!ControlHwnd
}
FileDialogActiveGetFolderPath(ByRef ActiveControlHwnd, ByRef ActiveControlClass, ByRef ActiveControlNn) {
SendPlay % "^{l}"
Start := A_TickCount
while ((ActiveControlClass ActiveControlNn) != "Edit2") {
if (A_TickCount - Start > 1000) {
return
}
Sleep % 5
}
ControlGetText Path, , % "ahk_id " ActiveControlHwnd
ControlSend, , % "{Escape}", % "ahk_id " ActiveControlHwnd
return Path
}
FileDialogActiveNavigate(Hwnd, Paths) {
ControlGet ControlHwnd, Hwnd, , % "Edit1", % "ahk_id " Hwnd
SetFocus(Hwnd, ControlHwnd)
ControlSetText, , % """" Join(Paths, """ """) """", % "ahk_id " ControlHwnd
SendPlay % "{Enter}{Delete}"
}
;@Ahk2Exe-Bin Unicode 64-bit.bin
;@Ahk2Exe-SetDescription night
;@Ahk2Exe-SetFileVersion 1.2.2
;@Ahk2Exe-SetInternalName night
;@Ahk2Exe-SetCopyright https://github.com/t5mat/night
;@Ahk2Exe-SetOrigFilename night.exe
;@Ahk2Exe-SetProductName night
;@Ahk2Exe-SetProductVersion 1.2.2
global Version := "1.2.2"
global Url := "https://github.com/t5mat/night"
global MacroPrefix := "~ night - "
global PleFolderName := "night"
global VersionMacroPrefix := "~ night "
global SelfPid := DllCall("GetCurrentProcessId", "UInt")
global SettingsPath
global AppExePath
global AppExeVersionInfo
global AppName
global KeyCommandsPath
global PlePath
global MacroKeys
FindAppExeWindow() {
return WinExist("ahk_exe i)^\Q" AppExePath "\E$")
}
FindAppProjectWindow() {
WinGet Hwnds, List, % "^" AppName "(?: .*?)? Project - .*$ ahk_class ^SteinbergWindowClass$ ahk_exe i)^\Q" AppExePath "\E$"
loop % Hwnds {
for _, Child in FindWindowChildrenRecursive(Hwnds%A_Index%) {
if (WinExist("ahk_class ^SteinbergChildWindowNoMouseHandlingClass$ ahk_id " Child)) {
return Hwnds%A_Index%
}
}
}
}
IsAppColorizeWindow(Hwnd) {
return (WinExist("^Colorize$ ahk_class ^SteinbergWindowClass$ ahk_exe i)^\Q" AppExePath "\E$ ahk_id " Hwnd) && FindWindowChildrenRecursive(Hwnd).Count() == 0)
}
global HwndContextFileDialog := (1 << 0)
global HwndContextSelf := (1 << 1)
global HwndContextApp := (1 << 2)
global HwndContextAppMenu := (1 << 3)
global HwndContextAppTitleBar := (1 << 4)
global HwndContextAppWindow := (1 << 5)
global HwndContextAppChildWindow := (1 << 6)
global HwndContextAppProjectWindow := (1 << 7)
global HwndContextAppColorizeWindow := (1 << 8)
FindHwndContext(Hwnd) {
Context := 0
if (IsDialogFileDialog(DialogTitle " ahk_id " Hwnd)) {
Context := Context | HwndContextFileDialog
}
if (WinExist("ahk_pid " SelfPid " ahk_id " Hwnd)) {
Context := Context | HwndContextSelf
} else if (WinExist("ahk_exe i)^\Q" AppExePath "\E$ ahk_id " Hwnd)) {
Context := Context | HwndContextApp
if (WinExist("ahk_class ^SmtgMain MenuWindowClass$ ahk_id " Hwnd)) {
Context := Context | HwndContextAppMenu
} else if (WinExist("ahk_class ^SmtgMain " AppName ".*$ ahk_id " Hwnd)) {
Context := Context | HwndContextAppTitleBar
} else if (WinExist("ahk_class ^SteinbergWindowClass$ ahk_id " Hwnd)) {
Context := Context | HwndContextAppWindow
Children := FindWindowChildrenRecursive(Hwnd)
if (Children.Count() == 0) {
if (WinExist("^Colorize$ ahk_id " Hwnd)) {
Context := Context | HwndContextAppColorizeWindow
}
} else {
for _, Child in Children {
if (WinExist("ahk_class ^SteinbergChildWindowNoMouseHandlingClass$ ahk_id " Child)) {
Context := Context | HwndContextAppChildWindow
if (WinExist("^" AppName "(?: .*?)? Project - .*$ ahk_id " Hwnd)) {
Context := Context | HwndContextAppProjectWindow
}
break
}
}
}
}
}
return Context
}
global AppMenuContextTrack := (1 << 0)
global AppMenuContextFolderTrack := (1 << 1)
global AppMenuContextTrackList := (1 << 2)
global AppMenuContextMixConsoleTracks := (1 << 3)
global AppMenuContextInsertSlot := (1 << 4)
global AppMenuContextNonEmptyInsertSlot := (1 << 5)
global AppMenuContextSendSlot := (1 << 6)
global AppMenuContextRack := (1 << 7)
global AppMenuContextInsertsRack := (1 << 8)
global AppMenuContextEditor := (1 << 9)
global AppMenuContextKeyEditor := (1 << 10)
global AppMenuContextSelected := (1 << 11)
global AppMenuContextSelectedAudio := (1 << 12)
global AppMenuContextSelectedMidi := (1 << 13)
FindAppMenuContext(Menu) {
Context := 0
if (FindMenuItemIndex(Menu, "Add Track...") != -1 && FindMenuItemIndex(Menu, "Global Meter Settings") != -1) {
Context |= AppMenuContextMixConsoleTracks
if (FindMenuItemIndex(Menu, "Link Selected Channels") != -1 || FindMenuItemIndex(Menu, "Unlink Selected Channels") != -1) {
Context |= AppMenuContextTrack
}
} else if (FindMenuItemIndex(Menu, "Select All Events") != -1) {
Context |= AppMenuContextTrackList | AppMenuContextTrack
if (FindMenuItemIndex(Menu, "Show Data on Folder Tracks") != -1) {
Context |= AppMenuContextFolderTrack
}
} else if (FindMenuItemIndex(Menu, "Hide All Automation") != -1) {
Context |= AppMenuContextTrackList
} else if (FindMenuItemIndex(Menu, "Set as last Pre-Fader Slot") != -1) {
Context |= AppMenuContextInsertSlot
if (FindMenuItemIndex(Menu, "Load Preset...") != -1) {
Context |= AppMenuContextNonEmptyInsertSlot
}
} else if (FindMenuItemIndex(Menu, "Clear Send") != -1) {
Context |= AppMenuContextSendSlot
} else if (FindMenuItemIndex(Menu, "Bypass") != -1 && FindMenuItemIndex(Menu, "Copy") != -1 && FindMenuItemIndex(Menu, "Paste") != -1 && FindMenuItemIndex(Menu, "Clear") != -1) {
Context |= AppMenuContextRack
if (FindMenuItemIndex(Menu, "Load FX Chain Preset...") != -1) {
Context |= AppMenuContextInsertsRack
}
} else if ((Tools := FindMenuItemIndex(Menu, "Tools")) != -1) {
Context |= AppMenuContextEditor
if ((ZoomToSelection := FindMenuItemIndex(Menu, "Zoom to Selection")) == -1 || GetMenuItemState(Menu, ZoomToSelection) & 0x2) {
if (FindMenuItemIndex(Menu, "Functions") != -1) {
Context |= AppMenuContextKeyEditor
}
} else {
Context |= AppMenuContextSelected
if (FindMenuItemIndex(Menu, "Create Sampler Track") != -1) {
Context |= AppMenuContextSelectedAudio
} else if (FindMenuItemIndex(Menu, "Processes") != -1) {
Context |= AppMenuContextSelectedAudio
} else if (FindMenuItemIndex(Menu, "Export MIDI Loop...") != -1) {
Context |= AppMenuContextSelectedMidi
} else if (FindMenuItemIndex(Menu, "Open Note Expression Editor") != -1) {
Context |= AppMenuContextKeyEditor | AppMenuContextSelectedMidi
}
}
}
return Context
}
IsValidKeyCommandsXml(KeyCommandsXml) {
return KeyCommandsXml.selectSingleNode("/KeyCommands/list[@name='Categories']") && KeyCommandsXml.selectSingleNode("/KeyCommands/list[@name='Macros']")
}
IsInstalled(Hash, KeyCommandsXml) {
return !!KeyCommandsXml.selectSingleNode("/KeyCommands/list[@name='Macros']/item/string[@name='Name' and @value='" VersionMacroPrefix Version " " Hash "']")
}
InstallKeyCommands(Xml, KeyCommandsXml) {
static NextAutoKey := Chr(0xA500)
Commands := KeyCommandsXml.selectSingleNode("/KeyCommands/list[@name='Categories']/item/string[@name='Name' and @value='Macro']/../list[@name='Commands']")
Macros := KeyCommandsXml.selectSingleNode("/KeyCommands/list[@name='Macros']")
for XmlMacro in Xml.selectNodes("/night/macros/item") {
XmlName := XmlMacro.selectSingleNode("string[@name='Name']").getAttribute("value")
MacroToAdd := XmlMacro.cloneNode(true)
MacroToAdd.selectSingleNode("string[@name='Name']").setAttribute("value", MacroPrefix XmlName)
if (Child := MacroToAdd.selectSingleNode("string[@name='Key']")) {
MacroToAdd.removeChild(Child)
}
for Macro in Macros.selectNodes("item") {
MacroName := Macro.selectSingleNode("string[@name='Name']").getAttribute("value")
if (XmlName == MacroName) {
Macros.replaceChild(MacroToAdd, Macro)
MacroToAdd :=
break
}
}
if (MacroToAdd) {
Macros.appendChild(MacroToAdd)
}
CommandToAdd := XmlMacro.cloneNode(true)
CommandToAdd.selectSingleNode("string[@name='Name']").setAttribute("value", MacroPrefix XmlName)
if (Child := MacroToAdd.selectSingleNode("string[@name='Commands']")) {
CommandToAdd.removeChild(Child)
}
CommandToAddKey := CommandToAdd.selectSingleNode("string[@name='Key']")
if (CommandToAddKey && CommandToAddKey.getAttribute("value") == "auto") {
CommandToAddKey.setAttribute("value", NextAutoKey)
NextAutoKey := Chr(Ord(NextAutoKey) + 1)
}
for Command in Commands.selectNodes("item") {
CommandName := Command.selectSingleNode("string[@name='Name']").getAttribute("value")
if (XmlName == CommandName) {
Commands.replaceChild(CommandToAdd, Command)
CommandToAdd :=
break
}
}
if (CommandToAdd) {
Commands.appendChild(CommandToAdd)
}
}
}
InstallPle(Xml, PlePath) {
FileCreateDir % (PleFolderPath := JoinPath(PlePath, PleFolderName))
for Ple in Xml.selectNodes("/night/ple/item") {
Name := Ple.selectSingleNode("string[@name='Name']").getAttribute("value")
Path := JoinPath(PleFolderPath, Name ".xml")
Data := Ple.selectSingleNode("Project_Logical_EditorPreset").xml
WriteFileUtf8(Path, Data)
}
}
InstallVersionMacro(Hash, KeyCommandsXml) {
Name := KeyCommandsXml.createElement("string")
Name.setAttribute("name", "Name")
Name.setAttribute("value", VersionMacroPrefix Version " " Hash)
Item := KeyCommandsXml.createElement("item")
Item.appendChild(Name)
Macros := KeyCommandsXml.selectSingleNode("/KeyCommands/list[@name='Macros']")
Macros.appendChild(Item)
}
Uninstall(KeyCommandsPath, PlePath) {
KeyCommandsData := ReadFileUtf8(KeyCommandsPath)
if ((KeyCommandsXml := LoadXml(KeyCommandsData))) {
UninstallKeyCommands(KeyCommandsXml)
WriteFileUtf8(KeyCommandsPath, KeyCommandsXml.xml)
}
UninstallPle(PlePath)
}
UninstallKeyCommands(KeyCommandsXml) {
Macros := KeyCommandsXml.selectSingleNode("/KeyCommands/list[@name='Macros']")
for Macro in Macros.selectNodes("item") {
Name := Macro.selectSingleNode("string[@name='Name']").getAttribute("value")
if (InStr(Name, VersionMacroPrefix, true) == 1 || InStr(Name, MacroPrefix, true) == 1) {
Macros.removeChild(Macro)
}
}
Commands := KeyCommandsXml.selectSingleNode("/KeyCommands/list[@name='Categories']/item/string[@name='Name' and @value='Macro']/../list[@name='Commands']")
for Command in Commands.selectNodes("item") {
Name := Command.selectSingleNode("string[@name='Name']").getAttribute("value")
if (InStr(Name, VersionMacroPrefix, true) == 1 || InStr(Name, MacroPrefix, true) == 1) {
Commands.removeChild(Command)
}
}
}
UninstallPle(PlePath) {
FileRemoveDir % JoinPath(PlePath, PleFolderName), true
}
LoadMacroKeys(KeyCommandsXml) {
Keys := []
Commands := KeyCommandsXml.selectSingleNode("/KeyCommands/list[@name='Categories']/item/string[@name='Name' and @value='Macro']/../list[@name='Commands']")
for Command in Commands.selectNodes("item") {
Name := Command.selectSingleNode("string[@name='Name']").getAttribute("value")
if (InStr(Name, MacroPrefix, true) == 1) {
Name := StrReplace(Name, MacroPrefix, "", , 1)
Key := "{" Command.selectSingleNode("string[@name='Key']").getAttribute("value") "}"
Keys[Name] := Key
}
}
return Keys
}
PatchProjectColors(ProjectPath, ColorsPath) {
if (!(File := FileOpen(ProjectPath, "a")) || !(Mapping := MapFile(File.__Handle, Address))) {
return false
}
Patched := 0
loop 128 {
IniRead Value, % ColorsPath, % "Colors", % A_Index, % A_Space
if (InStr(Value, "#", true) != 1 || StrLen(Value) != 7) {
continue
}
if (!CryptStringToBinary(SubStr(Value, 2) "00", Value, 0xC)) {
continue
}
Value := NumGet(&Value, "UInt")
Search := CryptUtf8ToString("Color " A_Index, 0xC | 0x40000000) "00efbbbfff"
SearchCount := CryptStringToBinary(Search, SearchBytes, 0xC)
Start := 0
loop {
Found := SearchBytesInBytes(Address + Start, File.Length - Start, &SearchBytes, SearchCount)
if (!Found) {
break
}
if (!Start) {
++Patched
}
Start := (Found - Address) + SearchCount + 4
if (NumGet(Address + Start - 1, "UChar") != 0) {
continue
}
NumPut(Value, Address + Start - 4, "UInt")
}
}
UnmapFile(Mapping, Address)
File.Close()
return Patched
}
ShowActiveAppMenuInfo() {
Gui ActiveAppMenuInfo:Destroy
if (!ActiveAppMenu) {
return
}
Rows := []
if ((ActiveAppMenuContext & AppMenuContextTrackList) || (ActiveAppMenuContext & AppMenuContextMixConsoleTracks)) {
Rows.Push(["n", "add track"])
Rows.Push(["Ctrl+n", "add track from track preset"])
Rows.Push(["Shift+n", "add track dialog"])
Rows.Push(["", ""])
Rows.Push(["Ctrl+a", "select all tracks"])
if (ActiveAppMenuContext & AppMenuContextTrack) {
Rows.Push(["", ""])
Rows.Push(["Tab", "show/hide editor"])
Rows.Push(["d/Delete/Backspace", "delete"])
Rows.Push(["Ctrl+d", "duplicate"])
Rows.Push(["e", "toggle enabled"])
Rows.Push(["h", "hide"])
Rows.Push(["c", "colorize"])
Rows.Push(["s", "send to a new FX channel"])
Rows.Push(["g", "send to a new group channel"])
Rows.Push(["v", "send to a new VCA fader"])
Rows.Push(["Ctrl+o", "load track preset"])
Rows.Push(["Ctrl+s", "save as track preset"])
Rows.Push(["Ctrl+Shift+s", "save as track archive"])
if (ActiveAppMenuContext & AppMenuContextTrackList) {
Rows.Push(["", ""])
Rows.Push(["i", "toggle edit in-place"])
Rows.Push(["f", "move to a new folder"])
Rows.Push(["a", "select all data"])
Rows.Push(["r", "clear all data"])
if (ActiveAppMenuContext & AppMenuContextFolderTrack) {
Rows.Push(["", ""])
Rows.Push(["Space", "collapse/expand first selected folder track"])
Rows.Push(["Ctrl+Space", "expand all folder tracks"])
Rows.Push(["Shift+Space", "collapse all folder tracks"])
} else {
Rows.Push(["", ""])
Rows.Push(["Space", "show used automation/hide automation"])
Rows.Push(["Ctrl+Space", "show all used automation"])
Rows.Push(["Shift+Space", "hide all automation"])
}
}
}
} else if (ActiveAppMenuContext & AppMenuContextInsertSlot) {
Rows.Push(["Tab", "open/focus plugin window"])
Rows.Push(["", "(doesn't work if mouse is under the bypass/arrow buttons)"])
Rows.Push(["Shift+Tab", "close plugin window"])
Rows.Push(["", "(doesn't work if mouse is under the bypass/arrow buttons)"])
Rows.Push(["d/Delete/Backspace", "delete"])
Rows.Push(["w", "replace"])
Rows.Push(["e", "toggle bypass"])
Rows.Push(["Shift+e", "toggle activated"])
Rows.Push(["f", "set as last pre-fader slot"])
Rows.Push(["s", "toggle sidechaining activated"])
Rows.Push(["q", "switch between A/B settings"])
Rows.Push(["Shift+q", "apply current settings to A and B"])
} else if (ActiveAppMenuContext & AppMenuContextSendSlot) {
Rows.Push(["d/Delete/Backspace", "clear"])
Rows.Push(["w", "replace"])
Rows.Push(["Ctrl+c", "copy"])
Rows.Push(["Ctrl+v", "paste"])
Rows.Push(["e", "toggle activated"])
Rows.Push(["f", "move to pre/post fader"])
Rows.Push(["r", "use default level"])
Rows.Push(["q", "set level to -oo"])
} else if (ActiveAppMenuContext & AppMenuContextRack) {
if (ActiveAppMenuContext & AppMenuContextInsertsRack) {
Rows.Push(["Tab", "open/focus all plugin windows"])
Rows.Push(["Shift+Tab", "close all plugin windows"])
Rows.Push(["e", "toggle bypass all"])
Rows.Push(["Ctrl+o", "load FX chain preset"])
Rows.Push(["Ctrl+s", "save as FX chain preset"])
} else {
Rows.Push(["e", "toggle bypass all"])
}
} else if (ActiveAppMenuContext & AppMenuContextEditor) {
if (!(ActiveAppMenuContext & AppMenuContextSelected)) {
Rows.Push(["z", "zoom to view horizontally"])
} else {
Rows.Push(["z", "zoom to selection horizontally"])
Rows.Push(["d/Delete/Backspace", "delete"])
Rows.Push(["c", "colorize"])
Rows.Push(["e", "toggle muted"])
Rows.Push(["Ctrl+d", "repeat"])
Rows.Push(["g", "glue"])
Rows.Push(["Shift+g", "dissolve"])
Rows.Push(["Shift+s", "convert shared to real copies"])
Rows.Push(["r", "render in place"])
Rows.Push(["Ctrl+r", "render in place (settings)"])
Rows.Push(["", ""])
Rows.Push(["Space", "locate selection start"])
Rows.Push(["Shift+Space", "move left/right locators to selection"])
Rows.Push(["Ctrl+Space", "move selection to cursor"])
Rows.Push(["", ""])
Rows.Push(["", "(range tool)"])
Rows.Push(["x", "split range"])
Rows.Push(["Shift+x", "crop range"])
if (ActiveAppMenuContext & AppMenuContextSelectedAudio) {
Rows.Push(["", ""])
Rows.Push(["", "(audio)"])
Rows.Push(["b", "bounce"])
Rows.Push(["p", "show in pool"])
} else if (ActiveAppMenuContext & AppMenuContextSelectedMidi) {
Rows.Push(["", ""])
Rows.Push(["", "(MIDI)"])
Rows.Push(["f", "open functions menu"])
Rows.Push(["q", "quantize event starts"])
Rows.Push(["Ctrl+q", "quantize event ends"])
Rows.Push(["Ctrl+Shift+q", "quantize event lengths"])
Rows.Push(["Shift+q", "reset quantize"])
Rows.Push(["v", "legato"])
Rows.Push(["Ctrl+s", "export first selected part as MIDI loop"])
}
}
if (ActiveAppMenuContext & AppMenuContextKeyEditor) {
Rows.Push(["", ""])
Rows.Push(["Tab", "toggle note expression editor"])
}
} else {
return
}
Length := 0
for _, Row in Rows {
Length := Max(Length, StrLen(Row[1]))
}
Text := ""
for Index, Row in Rows {
Text := Text " " Format("{:" Length "}", Row[1]) " " Row[2] " " (Index < Rows.Count() ? "`n" : "")
}
CoordMode Mouse, Screen
MouseGetPos X, Y
Monitor := GetMonitorFromPoint(X, Y)
GetMonitorWorkArea(Monitor, MonitorX, MonitorY, MonitorWidth, MonitorHeight)
MenuHwnd := WinExist(MenuTitle)
VarSetCapacity(MenuRect, 0x10)
DllCall("GetClientRect", "Ptr", MenuHwnd, "Ptr", &MenuRect)
DllCall("ClientToScreen", "Ptr", MenuHwnd, "Ptr", &MenuRect)
DllCall("ClientToScreen", "Ptr", MenuHwnd, "Ptr", &MenuRect + 0x8)
Gui ActiveAppMenuInfo:New, -Caption +Border +ToolWindow +E0x20 +AlwaysOnTop +HwndInfoHwnd
WinSet Transparent, 200, % "ahk_id " InfoHwnd
Gui ActiveAppMenuInfo:Font, s9 w900, % "Consolas"
Gui ActiveAppMenuInfo:Color, FFDB4C
Gui ActiveAppMenuInfo:Add, Text, , % Text
Gui ActiveAppMenuInfo:Show, Hide
WinGetPos, , , InfoWidth, InfoHeight, % "ahk_id " InfoHwnd
static Padding := 10
VarSetCapacity(InfoRightRect, 0x10)
NumPut(MonitorX + MonitorWidth - Padding - InfoWidth, &InfoRightRect + 0x0, "Int")
NumPut(MonitorY + MonitorHeight - Padding - InfoHeight, &InfoRightRect + 0x4, "Int")
NumPut(MonitorX + MonitorWidth - Padding, &InfoRightRect + 0x8, "Int")
NumPut(MonitorY + MonitorHeight - Padding, &InfoRightRect + 0xC, "Int")
VarSetCapacity(Dest, 0x10)
Left := DllCall("IntersectRect", "Ptr", &Dest, "Ptr", &MenuRect, "Ptr", &InfoRightRect, "Int")
WinMove % "ahk_id " InfoHwnd, , % (Left ? (MonitorX + Padding) : (MonitorX + MonitorWidth - Padding - InfoWidth)), % (MonitorY + MonitorHeight - Padding - InfoHeight)
Gui ActiveAppMenuInfo:Show, NoActivate
}
global ActiveHwnd
global ActiveHwndContext
global ActiveControlHwnd
global ActiveControlClass
global ActiveControlNN
global ActiveMenuCount
global ActiveAppMenu
global ActiveAppMenuContext
global MenuTime
global ColorizeHwnd
global LastAppWindowDestroyTime
global AddTrackHwnd
WaitActiveAppMenu(ByRef Menu, ByRef Context) {
Start := A_TickCount
while (!ActiveAppMenu) {
if (A_TickCount - Start > 1000) {
return false
}
Sleep % 5
}
Menu := ActiveAppMenu
Context := ActiveAppMenuContext
return true
}
IsActiveAppMenuTime() {
return (ActiveAppMenu || (MenuTime && A_TickCount - MenuTime <= 500))
}
SetEventHook() {
SetWinEventHook((EVENT_SYSTEM_FOREGROUND := 0x0003), EVENT_SYSTEM_FOREGROUND, "EventProc")
SetWinEventHook((EVENT_SYSTEM_MENUPOPUPSTART := 0x0006), EVENT_SYSTEM_MENUPOPUPSTART, "EventProc")
SetWinEventHook((EVENT_SYSTEM_MENUPOPUPEND := 0x0007), EVENT_SYSTEM_MENUPOPUPEND, "EventProc")
SetWinEventHook((EVENT_OBJECT_DESTROY := 0x8001), EVENT_OBJECT_DESTROY, "EventProc")
SetWinEventHook((EVENT_OBJECT_FOCUS := 0x8005), EVENT_OBJECT_FOCUS, "EventProc")
SetWinEventHook((EVENT_OBJECT_NAMECHANGE := 0x800C), EVENT_OBJECT_NAMECHANGE, "EventProc")
ActiveHwnd := WinExist("A")
ActiveHwndContext := FindHwndContext(ActiveHwnd)
ActiveControlHwnd := GetFocus(ActiveHwnd)
ActiveControlClass := GetHwndClass(ActiveControlHwnd)
ActiveControlNn := GetControlHwndNN(ActiveHwnd, ActiveControlHwnd, ActiveControlClass)
Menu := GetActiveMenu()
ActiveMenuCount := Menu ? 1 : 0
ActiveAppMenu := (ActiveHwndContext & HwndContextAppChildWindow) ? Menu :
ActiveAppMenuContext := FindAppMenuContext(ActiveAppMenu)
ShowActiveAppMenuInfo()
MenuTime := 0
ColorizeHwnd :=
LastAppWindowDestroyTime :=
AddTrackHwnd :=
}
EventProc(hWinEventHook, event, hwnd, idObject, idChild, idEventThread, dwmsEventTime) {